Lightpoint Tutorial

From Bohemia Interactive Community
Revision as of 01:30, 20 July 2020 by Lou Montana (talk | contribs) (Fix link)
Jump to navigation Jump to search

SideTOC

Basics

A lightpoint (glowing light source) is a non-physical object that shines a light. Unlike projectors or vehicle headlights, this light type cannot be directed into a beam and can only glow uniformously.

A lightpoint is local to the computer where the script has been called; one player could see a light in the dark while another would not have such light "object" created.


How to

The list of all lightpoint commands can be found in the Lights command group category.

Informative

Create a lightpoint

private _lightpoint = "#lightpoint" createVehicleLocal player modelToWorld [0,2,1.5];

Informative

Set light colour

Colour

_lightpoint setLightColor [0.25, 1, 1];

Informative

Ambient Colour

_lightpoint setLightAmbient [1, 1, 1]; // sets the colour applied to the surroundings

Set flare

Informative

4

_lightpoint setLightUseFlare true;

4

_lightpoint setLightFlareSize 1; // in meter

4

_lightpoint setLightFlareMaxDistance 100; // in meter

Set light brightness

Set brightness

_lightpoint setLightBrightness 8;

4

_lightpoint setLightIntensity 3000;

4

_lightpoint setLightAttenuation [0, 2, 4, 4, 0, 9, 10]; // [start, constant, linear, quadratic, hardLimitStart, hardLimitEnd]

Informative

3

_lightpoint setLightDayLight true; // Only for light itself, not the flare

Delete lightpoint

deleteVehicle _lightpoint; // as simple as that

Full examples

Dark Souls

skipTime -daytime;

_lightpoint = "#lightpoint" createVehicleLocal [0,0,0];
_lightpoint attachTo [player, [0, 0, 1.5]];
_lightpoint setLightColor [0,0,0];
_lightpoint setLightAmbient [1,0.8, 0.25];
_lightpoint setLightBrightness 0.15;

Contact

skipTime -daytime;

private _position = player modelToWorld [0, 20, 1.5];
private _lightpoint = "#lightpoint" createVehicleLocal _position;
_lightpoint setLightColor [0,1,1];
_lightpoint setLightAmbient [0.2,0.0,0.3];
_lightpoint setLightUseFlare true;
_lightpoint setLightFlareSize 3;
_lightpoint setLightFlareMaxDistance 3.5;
_lightpoint setLightBrightness 4;
_lightpoint setLightDayLight true;

_lightpoint spawn {
	while { sleep 0.05; player distance _this > 2 } do
	{
		_this setLightBrightness 4 max (40 / (player distance _this));
	};
	deleteVehicle _this;
};


See also