addAction

1.1

GAGlobalLELocal

Hover & click on the images for description

Description

Description:

Template:Feature arma3 Adds an entry to the action menu of an object (scroll wheel menu). The action can only be activated when in proximity to the object (eg: building). Adding an action to the player obviously makes that action available to the player at all times. The appearance of onscreen text could be further tweaked with setUserActionText. For event handling of user interaction see inGameUISetEventHandler

This command has local effect. Created action is only available on the computer where command was executed. To make action available to all players, command must be executed on all connected clients (see remoteExec). addAction is also ignored on dedicated server, because of no user interface. In Arma 3 addAction does not work on animals. This is intended behavior.

• Since Arma 3 v1.63.136787, two new params are available: radius and unconscious.
  
• Since Arma 3 v1.69.140846, new param is available: selection.
  
• Since Arma 3 v1.81.144102, new param is available: memoryPoint & radius param is now always referencing distance between player eye position (eyePos) and object selection, memory point or [0,0,0]; in this order, depending on what params are supplied to the command.

Groups:

Uncategorised

Syntax

Syntax:

object addAction [title, script, arguments, priority, showWindow, hideOnUse, shortcut, condition, radius, unconscious, selection, memoryPoint]

Parameters:

object: Object - unit, vehicle or static object

[title, script, arguments, priority, showWindow, hideOnUse, shortcut, condition, radius, unconscious, selection]: Array

title: String - The action name which is displayed in the action menu, may contain XML like syntax. Because of that < and > symbols will be interpreted as opening and closing XML tags. To avoid this use &lt; for < and &gt; for >. The title text can be changed with setUserActionText

script: String or Code - Either path to the script file, relative to the mission folder or string with code or the actual script code. If the string is a path to script file, the script file *must* have extension .SQS or .SQF. The script, whether it is a file or a code, will run in scheduled environment, i.e. it is ok to use sleep.

• Parameters array passed to the script upon activation in _this variable is: [target, caller, ID, arguments]
• target (_this select 0): Object - the object which the action is assigned to
• caller (_this select 1): Object - the unit that activated the action
• ID (_this select 2): Number - ID of the activated action (same as ID returned by addAction)
• arguments (_this select 3): Anything - arguments given to the script if you are using the extended syntax

arguments (Optional): Anything - Arguments to pass to the script (will be _this select 3 inside the script). If Array is used as an argument for example, its 1st element reference would be _this select 3 select 0. Default value: nil

priority (Optional): Number - Priority value of the action. Actions will be arranged in descending order according to this value. Every game action has a preset priority value. Value can be negative or decimal fraction. Actions with same values will be arranged in order which they were made, newest at the bottom. The bigger the number the higher the action will be positioned on the menu. Typical range is 0 (low priority. Eg: 'Get out') to 6 (high priority. Eg: 'Auto-hover on'). Default value: 1.5

showWindow (Optional): Boolean - If set to true, players see "Titletext" at mid-lower screen, as they approach the object. Only the title text for the action with highest priority and 'showWindow true' will be shown. Setting it to false disables the feature. Default value: true

hideOnUse (Optional): Boolean - If set to true, it will hide the action menu after selecting that action. If set to false, it will leave the action menu open and visible after selecting that action, leaving the same action highlighted, for the purpose of allowing you to reselect that same action quickly, or to select another action. Default value: true

shortcut (Optional): String - One of the key names defined in bin.pbo (e.g. "moveForward"). Adding available shortcut will bind corresponding keyboard key to this action. Shortcut availability can be tested with inputAction command. Default value: ""

condition (Optional): String - script code that must return true for the action to be shown. Special variables passed to the script code are _target (object to which action is attached to) and _this (caller/executing person). Default value: "true"

NOTE: condition is evaluated on each frame in |non-scheduled environment. If action is added to some object and not to player, condition will only get evaluated IF player is closer than ~50m to the object surface AND is looking at the object. If action is added to player, the condition is evaluated all the time.

radius (Optional): Number - 3D distance in meters the unit activating the action must be within to activate it. -1 disables this radius. Default (and max) value: 50

unconscious (Optional): Boolean - if true will be shown to incapacitated player (see setUnconscious, lifeState). Default value: false

selection (Optional): String - named selection in Geometry LOD to which the action is attached. Default value: ""

memoryPoint (Optional): String - memory point on the object to which the action is attached. If parameter selection is supplied, parameter memoryPoint is not used. Default value: ""

Return Value:

Number - The ID of the action is returned. IDs are incrementing. The first given action to each unit has got the ID 0, the second the ID 1 etc. ID's are also passed to the called script and used to remove an action with removeAction

Examples

Example 1:

Short and sweet:player addAction ["A Useless Action That Does Nothing", {}]; player addAction ["<t color='#FF0000'>This Useless Action Is RED</t>", {hint "RED"}]; player addAction ["Hint Hello!", {hint format ["Hello %1!", _this select 3]}, name player]; player addAction ["String Exec", "hint 'this is also compiled'"];

Example 2:

SQF file example: _act = player addAction ["Exec the file", "somescript.sqf"] somescript.sqf: hint str _this;

Example 3:

SQS file example: _genAct = generator addAction ["Switch on generator", "activate_generator.sqs"] activate_generator.sqs: _gen = _this select 0 _caller = _this select 1 _id = _this select 2 ; remove the action once it is activated _gen removeAction _id This example shows an action called "Switch on generator" added to an object with the name 'generator'. As soon as the player gets close to this object, he can execute the given action via the action menu. Then the script 'activate_generator.sqs' is executed, which in our example only removes the action from the generator.

Example 4:

Create object on dedicated server and add action to the object on every client:if (isDedicated) then { _obj = "some_obj_class" createVehicle [1234, 1234, 0]; [_obj, ["Greetings!", {hint "Hello!"}]] remoteExec ["addAction", -2, _obj]; };

Additional Information

See also:

actionIDsactionParamssetUserActionTextinGameUISetEventHandlershowHUDinputActionremoveActionremoveAllActionsactionBIS_fnc_holdActionAdd

Notes

Report bugs on the Feedback Tracker and/or discuss them on the Arma Discord or on the Forums.
Only post proven facts here! Add Note

Notes

Posted on August 2, 2006 - 10:10

hardrock

An easy way to keep track of and remove actions is to store the IDs of the actions in variables. This can be accomplished by doing the following: _myaction = player addAction ["Hello", "hello.sqs"]; This stores the action's ID in the local variable "_myaction" and assists in keeping track of the action ID. To remove the above action, you would use the following line: player removeAction _myaction;

Bottom Section

Posted on June 19, 2014 - 15:01 (UTC)

Krzmbrzl00

If executing actual script code like this: _unit addAction [ "yourAction", { hint "A line of code" } ];

you can have a user action that uses and/or affects variables used elsewhere in the script that adds the action.

But beware!
The variable(s) must be global otherwise it won't work! i.e.

Fail

_variable = false;
_unit addAction [ "action", { _variable = true } ];

Succeed

variable = false;
_unit addAction [ "action", { variable = true } ];

Posted on March 10, 2015 - 09:55 (UTC)

Killzone Kid

Actionception:actions = []; actions set [0, player addAction ["Actionception", { if (count actions == 1) then { actions set [1, player addAction [" Actionception ", { if (count actions == 2) then { actions set [2, player addAction [" Actionception ", { if (count actions == 3) then { actions set [3, player addAction [" Actionception ", { { player removeAction _x; } forEach actions; }, [], 10, false, true]]; }; }, [], 10, false, false]]; }; }, [], 10, false, false]]; }; }, [], 10, false, false]]; Function to remove user actions with unknown ids: KK_fnc_removeUnknownUserActions = { for "_i" from 0 to (player addAction ["",""]) do { if !(_i in _this) then { player removeAction _i; }; }; }; To test: for "_i" from 0 to 9 do { player addAction ["Action #" + str _i, { [0,5,6] call KK_fnc_removeUnknownUserActions; }]; }; Removes all user actions but 0, 5 and 6.

Posted on July 18, 2016 - 01:13 (UTC)

longbow

A3 v1.62.137494: Condition is not evaluated when map is opened (and probably also true for other displays or opened dialog)

Posted on October 28, 2017 - 04:16 (UTC)

Midnighters

addAction with all the default parameters: addAction["Cookies",{},nil,1.5,true,true,"","true",15,false,""];