waitUntil

-wrong parameter ("Arma") defined!-1.00

Hover & click on the images for description

Description

Description:

Suspends execution of scheduled script until the given condition satisfied. This command will loop and call the code inside {} mostly every frame (depends on complexity of condition and overall engine load) until the code returns true. The execution of the rest of the script therefore will be suspended until waitUntil completes.

If the very first execution of the code returns true the command will exit immediately, therefore it will not produce any "Suspending not allowed in this context" error when used inside non-scheduled script. For all other uses it must be executed in environment that allows suspension (canSuspend), such as spawned or execVMed code.

⚠

Since Arma 3 v1.93.145618, a condition returning anything other than true or false will result in an appropriate type error.

Problems:

For some unknown reason if you have waitUntil loop active and game is saved/loaded, some variables in the expression may appear undefined for a short time. As a workaround, assign expression to a variable and make sure it is defined before waitUntil checks it: waitUntil { private _expression = var1 && (var2 > 10); !isNil "_expression" && { _expression } };

Groups:

Program Flow

Syntax

Syntax:

waitUntil condition

Parameters:

condition: Code - the expression that must return a Boolean, true to finish waiting or false to continue waiting

Return Value:

Anything - the value the condition evaluates to when the wait is over (normally true)

Examples

Example 1:

waitUntil { not alive player };

Example 2:

_i = 0; waitUntil { _i = _i + 1; _i >= 100 };

Example 3:

waitUntil {sleep 1; not alive player }; // Checks every 1 second

Example 4:

An on-the-fly custom event handler: _myEH = ["ZoomIn"] spawn { while { true } do { waitUntil { inputAction (_this select 0) == 1; }; diag_log format ["%1 @ %2", _this select 0, diag_tickTime]; }; }; Although perhaps better to use onEachFrame, depending on the application.

Example 5:

Use getVariable with default value:// bad waitUntil { bank getVariable "money" > 0 }; // good waitUntil { bank getVariable ["money", 0] > 0 }; // bad waitUntil { isready }; // good waitUntil { missionNamespace getVariable ["isready", false] }; Always return Boolean:// bad waitUntil { if (not alive player) exitWith {}; _time = _time + 1 }; // good waitUntil { if (not alive player) exitWith { true }; _time = _time + 1; false }; // perfect waitUntil { not alive player };

Additional Information

See also:

sleepuiSleepcanSuspendspawnexecVMwhileControl Structures

Notes

Report bugs on the Feedback Tracker and/or discuss them on the Arma Discord or on the Forums.
Only post proven facts here! Add Note

Notes

Posted on December 20, 2006 - 19:55

CrashDome

waitUntil suspends both SQF functions and SQF scripts. In functions, the calling script is still in suspension due to waiting for a return from the call command. The game engine will continue, however. See Function for more detail.

Posted on April 2, 2010 - 17:10

Roehre

Prior to Arma 3 v1.92.145618 if waitUntil uses an undefined call code, waitUntil won't release, even when this code is separated from other conditions through or. Be warned that this won't cause an error message.

Posted on Jan 07, 2011

kju

By default the cycle time for the condition check is per frame. Look at the example 3, how to set it at a lower rate yourself. Often times one does not need per-frame checking. Saves a lot CPU checks; especially when the condition is complex to compute.

Posted on December 13, 2014 - 23:25 (UTC)

Commy2

If you want to use waitUntil together with exitWith, remember that the loop only exits if the code block returns true.

It should look like this: waitUntil { // exit loop if the unit gets deleted {{cc|if (isNull _unit) exitWith { true }; // has to return true to continue !alive _unit; };