createDiaryRecord

1.00

LELocal

Hover & click on the images for description

Description

Description:

Creates a diary entry. Supported tags and their parameters:

• img
  • image: String - path to image. When present, any element with it will be displayed as image.
  • width: Number - image width in pixels.
  • height: Number - image height in pixels.
• font
  • color: String - HTML color in format #aarrggbb or #rrggbb
  • size: Number - font height in pixels.
  • face: String - font type (class from CfgFontFamilies)
• br
• marker
  • name: String - marker name
• execute
  • expression: String - executed code
• executeClose
  • expression: String - executed code, diary is closed afterwards
• log
  • subject: String - subject name.
  • record: String - record name (e.g. "Record6" or "Unit1059524")
• gear
  • unit: Number - unit ID
• teamSwitch
  • unit: Number - unit ID
• kick
  • id: Number - player ID
• ban
  • id: Number - player ID
• mute
  • id: Number - player ID
• currentTask
  • id: Number - task ID

ⓘ

If createDiaryRecord command fails, it returns null record, but since there is no null record unary command, you can make a variable and compare against it.

private _nullRecord = objNull createDiaryRecord [];

if (player createDiaryRecord ["Diarea", ["title", "description"]] isEqualTo _nullRecord) then { hint "Failed" };

Groups:

Uncategorised

Syntax

Syntax:

unitName createDiaryRecord [subject, text, task, state, showTitle]

Parameters:

unitName: Object

[subject, text, task, state, showTitle]: Array

subject: String

text: String

task: (optional): Task

state: (optional): String

showTitle (Optional): Boolean - Title visibility. Default: true DEV

Return Value:

Diary Record

Alternative Syntax

Syntax:

unitName createDiaryRecord [subject, [title, text], task, state, showTitle]

Parameters:

unitName: Object

[subject, [title, text], task, state, showTitle]: Array

subject: String

[title, text]: Array

title: String

text: String

task: (optional): Task

state: (optional):String

showTitle (Optional): Boolean - Title visibility. Default: true DEV

Return Value:

Diary Record

Examples

Example 1:

player createDiaryRecord ["Diary", ["Intel", "Enemy base is on grid <marker name='enemyBase'>161170</marker>"]]

Example 2:

player createDiaryRecord ["Diary", "Information gathered.<br /><img image='wellDone_ca.paa' />"]

Example 3:

player createDiaryRecord ["Diary",["No Title","description"],taskNull,"",false];

Example 4:

player createDiaryRecord ["Diary",["Font tag","<font color='#7FFF00' size='30' face='TahomaB'>This will changed text size, colour and font</font>"],taskNull,"",false];

Example 5:

player createDiaryRecord ["Diary",["Image","<img image='\A3\Ui_F_Curator\Data\Logos\arma3_curator_artwork.jpg' width='500' height='800'/>"],taskNull,"",false];

Example 6:

player createDiaryRecord ["Diary",["Linebreak","Line1<br></br>Line2<br></br><br></br>Line4"],taskNull,"",false];

Example 7:

player createDiaryRecord ["Diary",["Execute","<execute expression='hint ""Some code"";'>Some text</execute>"],taskNull,"",false];

Example 8:

player createDiaryRecord ["Diary",["ExecuteClose","<executeClose expression=""hint 'Diary closed';"">Close Diary</executeClose>"],taskNull,"",false];

Additional Information

See also:

processDiaryLinkcreateDiaryLinkcreateDiarySubjectdiarySubjectExists

Notes

Report bugs on the Feedback Tracker and/or discuss them on the Arma Discord or on the Forums.
Only post proven facts here! Add Note

Bottom Section

Posted on March 24, 2017 - 20:11 (UTC)

Tankbuster

When adding multiple diary records, be aware that they appear in reverse order. ie the first one you add will appear last and the last one you add will be first.

Posted on May 21, 2018 - 08:21 (UTC)

Kalthramis

To add an entry under the 'Briefing' subject, which is available by default, use "Diary" as the subject.