1.001.501.000.50

LALocalLELocal

Hover & click on the images for description

Description

Description:

Creates a Diary entry. Supported tags and their parameters: Show text

Tag	Options	Example
img	image: String - path to image. When present, any element with it will be displayed as image. width: Number - image width in pixels. height: Number - image height in pixels. 2.10 title: String - tooltip to show on mouse over image 2.10 src: String - alternative to 'image' Maximum width supported seems to be 370 pixels as a wider image will be cut off. Height should be calculated with the aspect ratio of the image. height = 370; ratio = 16/9; height = width / ratio;	<img image="picture.paa" width="128" height="64" /> Since Arma 3 v2.10: <img src="picture.paa" width="128" height="64" title="this is an image" />
font	color: String - HTML color in format #aarrggbb or #rrggbb size: Number - font height in pixels (default: 14) face: String - font type (see Fonts)	<font color="#FF00FF" size="16" face="LucidaConsoleB">Hello there</font>
br	N/A	Line 1<br />Line 2
marker	name: String - marker name	<marker name="respawn_west">Respawn point</marker>
execute	expression: String - executed code	<execute expression="player setDamage 1">Die!</execute>
executeClose	expression: String - executed code, diary is closed afterwards	<executeClose expression="player setDamage 1">Die and close</executeClose>
log	subject: String - subject name. record: String - record ID (e.g. "Record6" or "Unit1059524")	<log subject="Hello">Get to the "Hello" subject</log> <log subject="Hello" record="Record0">Go to the first record added to "Hello"</log>
gear	unit: Number - unit ID	<gear unit="123456">Open unit 123456's gear</gear>
teamSwitch	unit: Number - unit ID	<teamSwitch unit="123456">Switch to unit 123456</teamSwitch>
kick	id: Number - unit ID	<kick unit="123456">Kick player unit 123456</kick>
ban	id: Number - unit ID	<ban unit="123456">ban player unit 123456</ban>
mute	id: Number - unit ID	<mute unit="123456">mute player unit 123456</mute>
voteadmin	id: Number - unit ID	<voteadmin unit="123456">vote admin unit 123456</voteadmin>
votekick	id: Number - unit ID	<votekick unit="123456">vote kick player unit 123456</votekick>
currentTask	id: Number - task ID action: String - 'n' or 's' (select)	<currentTask id="my_task">get to my_task task</currentTask>

↑ Back to spoiler's top

ⓘ

If the createDiaryRecord command fails, it returns a null record.

Before Arma 3 v2.00, isNull did not work with the diary record type and diaryRecordNull did not exist. In order to verify a null record, it is possible to create a variable and compare against it:

Copy

private _recordNull = objNull createDiaryRecord []; private _createdRecord = player createDiaryRecord ["Diary", ["Title", "Description"]]; if (_createdRecord isEqualTo _recordNull) then { hint "Failed"; };

Groups:

Briefing

Syntax

Syntax:

player createDiaryRecord [subject, textInfo, task, taskState, showTitle]

Parameters:

player: Object

subject: String

textInfo: String or Array of Strings - can be:

• String - the record's content - its title will be empty
• Array of Strings - format [title, text, icon]:
  • title: String
  • text: String
  • 2.10 icon: String - (Optional) icon to show next to the title

task: Task - (Optional, default taskNull)

taskState: String - (Optional, default "NONE") changes the state of the given task. Can be one of:

• "NONE"
• "CREATED"
• "ASSIGNED"
• "SUCCEEDED"
• "FAILED"
• "CANCELED"

since 1.96

showTitle: Boolean - (Optional, default true) whether or not to show title in the description section as well

Return Value:

Diary Record

Examples

Example 1:

Copy

player createDiaryRecord ["Diary", ["Intel", "Enemy base is on grid <marker name='enemyBase'>161170</marker>"]];

Example 2:

Copy

player createDiaryRecord ["Diary", "Information gathered.<br /><img image='wellDone_ca.paa' />"];

Example 3:

Copy

player createDiaryRecord ["Diary", ["Title", "Description"], taskNull, "", false];

Example 4:

Copy

player createDiaryRecord [ "Diary", ["Font tag", "<font color='#7FFF00' size='30' face='TahomaB'>This will changed text size, colour and font</font>"], taskNull, "", false ];

Example 5:

Copy

player createDiaryRecord [ "Diary", ["Image", "<img image='\A3\Ui_F_Curator\Data\Logos\arma3_curator_artwork.jpg' width='500' height='800' />"], taskNull, "", false ];

Example 6:

Copy

player createDiaryRecord ["Diary", ["Linebreak", "Line1<br />Line2<br /><br />Line4"], taskNull, "", false];

Example 7:

Copy

player createDiaryRecord ["Diary", ["Execute","<execute expression='hint ""Some code"";'>Some text</execute>"], taskNull, "", false];

Example 8:

Copy

player createDiaryRecord ["Diary", ["ExecuteClose", "<executeClose expression=""hint 'Diary closed';"">Close Diary</executeClose>"], taskNull, "", false];

Additional Information

See also:

allDiaryRecords processDiaryLink createDiaryLink createDiarySubject diarySubjectExists setDiaryRecordText removeDiaryRecord

Notes

Report bugs on the Feedback Tracker and/or discuss them on the Arma Discord or on the Forums.
Only post proven facts here! Add Note