select

1.001.001.001.001.501.000.50

Hover & click on the images for description

Description

Description:

Selects an element from an array, config entry from Config or substring from a string or a range from an array.

ⓘ

Substring version of `select` operates with ANSI charset, if Unicode support is desired, see forceUnicode

Groups:

ArraysStringsConfig

Syntax 1

Syntax:

array select index

Parameters:

array: Array

index: Number - Index 0 denotes the first element, 1 the second, etc. If index has decimal places it gets rounded down for fractions less than or equal .5, otherwise it gets rounded up.

Return Value:

Anything - a reference to array element given by its index

Syntax 2

Syntax:

array select boolean

Parameters:

array: Array

boolean: Boolean - true => 1, false => 0

Return Value:

Anything - a reference to array element given by its index (false - 0, true - 1)

Syntax 3

Syntax:

config select index

Parameters:

config: Config

index: Number - Index 0 denotes the first element, 1 the second, etc. If index has decimal places it gets rounded down for fractions less than or equal .5, otherwise it gets rounded up.

Return Value:

Config

1.28

Syntax 4

Syntax:

string select [start, length]

Parameters:

string: String

[start, length]: Array

start: Number - String position to start selection from. 0 denotes the first character of the string, 1 the second, etc. If passed number has decimal places it gets rounded down for fractions less than or equal .5, otherwise it gets rounded up.

length: Number - (Optional, default string length) number of characters to select

Return Value:

String

1.32

Syntax 5

Syntax:

array select [start, count]

Parameters:

array: Array

[start, count]: Array

start: Number - Array index to start selection from.

count: Number - Number of array elements to select. If the selected range exceeds source array boundaries, selection will be made up to the last element of the array.

Return Value:

Array - a new array from selection

1.56

Syntax 6

Syntax:

array select expression

Parameters:

array: Array

expression: Code - expression that is expected to return Boolean or Nothing. If true is returned, the original array value of currently tested element _x will be added to the output array

Return Value:

Array - a new array of all elements from the original array that satisfied expression condition

Examples

Example 1:

["a", "b", "c", "d"] select 2; // result is "c" position player select 2; // result is Z coordinate of player position

Example 2:

["", currentWeapon player] select alive player; // if player is dead, "" is selected

Example 3:

(configFile >> "cfgVehicles" >> typeOf vehicle player >> "Turrets") select 0 >> "gunnerAction";

Example 4:

hint str ("japa is the man!" select [8]); // the man! hint str ("japa is the man!" select [0, 7]); // japa is

Example 5:

hint str ([1,2,3,4,5,6] select [1, 4]); // [2,3,4,5]

Example 6:

_even = [1,2,3,4,5,6,7,8,9,0] select { _x % 2 == 0 }; // returns [2, 4, 6, 8, 0]

Example 7:

JavaScript endsWith() alternative:private _fnc_endsWith = { params ["_string", "_endswith"]; _string select [count _string - count _endswith] isEqualTo _endswith }; ["Arma 3", "3"] call _fnc_endsWith; // true

Additional Information

See also:

a hash b selectRandom selectRandomWeighted set resize reverse in find findIf toArray toStringforEachcountdeleteAtdeleteRangeappendsortparamparamssplitStringjoinStringpushBackpushBackUniqueapplyforceUnicode

Notes

Report bugs on the Feedback Tracker and/or discuss them on the Arma Discord or on the Forums.
Only post proven facts here! Add Note

General Barron - c

Posted on Mar 03, 2009 - 02:02 (UTC)

When combined with the count command, this can be used to read all entries out of a config; even when you don't know exactly how many entries there will be. See the notes under count for more info.

Killzone Kid - c

Posted on Sep 28, 2013 - 00:53 (UTC)

Rounding of fractions with select is not the same as when you use round command: _roundThis = 0.5; hint str ([0,1] select _roundThis); // 0 hint str ([0,1] select round _roundThis); // 1

Pierre MGI - c

Posted on Jul 14, 2016 - 04:18 (UTC)

You can substract array from array using select: _array = [[1], [2], [3]]; _sub = [2]; _array - _sub; // [[1], [2], [3]] _array select { !(_x isEqualTo _sub) }; // [[1], [3]] [[1],[2],[2],[2],[2],[3]] select { !(_x isEqualTo _sub) }; // [[1], [3]]

Killzone Kid - c

Posted on Jun 22, 2015 - 23:23 (UTC)

Usually when select tries to pick up element out of range, Arma throws "division by zero" error. However there are exceptions. Basically as long as index of element you are selecting is less then or equal to array size, you will get no error. [] select 0; // ok, result is nil [1,2,3] select 3; // ok, result is nil [1,2,3] select 4; // division by zero

Commy2 - c

Posted on Nov 12, 2016 - 22:36 (UTC)

It is not safe to escape the code block of alternative syntax #5 with exitWith, breakOut etc: x3 = [1,2,3,4,5] select { if (_x == 3) exitWith { false; }; true }; // could be expected to be: x3 = [1,2,4,5] // actual result: x3 = false

Igneous01 - c

Posted on Feb 14, 2017 - 16:26 (UTC)

Syntax #5 is the equivalent of passing in a predicate that returns a boolean. In SQF, a piece of code will always return what the last executed command returned. myAliveUnits = allUnits select { alive _x }; // alive returns a boolean, the last statement run was alive _x, // therefore this piece of code will return a true/false to the select command myEastGroups = allGroups select { side _x == east }; // returns all east groups my4ManGroups = allGroups select { count units _x == 4 }; // returns all groups that have 4 men in them unitsThatDetectedMe = allUnits select { _x knowsAbout player > 0.1 }; // returns a list of units that have detected the player