BIS_fnc_VRTimer

1.00

LELocal

Hover & click on the images for description

Description

Description:

Timer for VR and time trials. The following missionNamespace variables can be used:

• BIS_stopTimer: set to true to stop the timer. Once stopped, the function must be executed again to restart the timer
• RscFiringDrillTime_current: fill with Structured Text to display text instead of timer (when timer is stopped)
• RscFiringDrillTime_done: set to true to close the display. Stop the timer first

Execution:

call

Groups:

Uncategorised

Syntax

Syntax:

[colour] spawn BIS_fnc_VRTimer

Parameters:

colour: String (Optional, default (["IGUI", "WARNING_RGB"] call BIS_fnc_displayColorGet) call BIS_fnc_colorRGBtoHTML) timer colour in HTML format (#RRGGBB)

Return Value:

Nothing

Examples

Example 1:

[] spawn BIS_fnc_VRTimer;

Example 2:

"#025D00" spawn BIS_fnc_VRTimer;

Example 3:

["#025D00"] spawn BIS_fnc_VRTimer;

Additional Information

See also:

BIS_fnc_displayColorGetBIS_fnc_colorRGBtoHTML

Notes

Report bugs on the Feedback Tracker and/or discuss them on the Arma Discord or on the Forums.
Only post proven facts here! Add Note

Notes

Posted on June 04, 2018 - 19:50 (UTC)

Lou Montana

Here is a countdown, inspired by this function:
Show function

LM_fnc_timeoutCountdown = {

	params [
		["_time", 30, [0]],
		["_colour", "#FFFFFF", [""]]
	];
	private _timeout = time + _time;
	RscFiringDrillTime_done = false;
	1 cutRsc ["RscFiringDrillTime", "PLAIN"];
	while { time < _timeout } do
	{
		private _remainingTime = _timeout - time;
		private _timeFormat = [_remainingTime, "MM:SS.MS", true] call BIS_fnc_secondsToString;
		private _text = format ["<t align='left' color='%1'><img image='%2' />%3:%4<t size='0.8'>.%5</t>",
			_colour,
			"A3\Modules_F_Beta\data\FiringDrills\timer_ca",
			_timeFormat select 0,
			_timeFormat select 1,
			_timeFormat select 2
		];
		RscFiringDrillTime_current = parseText _text;
		sleep 0.01;
	};
	private _timeFormat = [0, "MM:SS.MS", true] call BIS_fnc_secondsToString;
	RscFiringDrillTime_current = parseText format ["<t align='left' color='%1'><img image='%2' />%3:%4<t size='0.8'>.%5</t>",
		_colour,
		"A3\Modules_F_Beta\data\FiringDrills\timer_ca",
		_timeFormat select 0,
		_timeFormat select 1,
		_timeFormat select 2];
	sleep 4;
	RscFiringDrillTime_done = true;
};

↑ Back to spoiler's top

and to use it: [10, "#FF5500"] spawn LM_fnc_timeoutCountdown;