addAction

0.50

GAGlobalLELocal

Hover & click on the images for description

Description

Description:

This command syntax is for Arma 3 only. For TKOH and older Template:armaSeries games see addAction TKOH.

Adds an entry to the action menu of an object (scroll wheel menu). The action can only be activated when in proximity to the object (default 50m) and look at it. Adding an action to the player makes that action available to the player at all times.
The appearance of onscreen text can be further tweaked with setUserActionText. For event handling of user interaction see inGameUISetEventHandler.

ⓘ

addAction does not work on agents (including animals) and simple objects, this is intended behavior.

Groups:

Interaction

Syntax

Syntax:

object addAction [title, script, arguments, priority, showWindow, hideOnUse, shortcut, condition, radius, unconscious, selection, memoryPoint]

Parameters:

object:

Object - unit, vehicle or static object

title:

String - The action name which is displayed in the action menu, may contain Structured Text. Because of that < and > symbols will be interpreted as opening and closing XML tags. To avoid this use &lt; for < and &gt; for >. The title text can be changed with setUserActionText

script:

String or Code - Either path to the script file, relative to the mission folder or string with code or the actual script code. If the string is a path to script file, the script file must have extension .SQS or .SQF. The script, whether it is a file or a code, will run in scheduled environment, i.e. it is ok to use sleep.
Parameters array passed to the script upon activation in _this variable is:

params ["_target", "_caller", "_actionId", "_arguments"];

• target (_this select 0): Object - the object which the action is assigned to
• caller (_this select 1): Object - the unit that activated the action
• actionId (_this select 2): Number - activated action's ID (same as addAction's return value)
• arguments (_this select 3): Anything - arguments given to the script if you are using the extended syntax

arguments:

Anything - (Optional, default nil) arguments to pass to the script (will be _this select 3 inside the script). If Array is used as an argument for example, its first element reference would be _this select 3 select 0

priority:

Number - (Optional, default 1.5) priority value of the action. Actions will be arranged in descending order according to this value. Every game action has a preset priority value. Value can be negative or decimal fraction. Actions with same values will be arranged in order which they were made, newest at the bottom. The bigger the number the higher the action will be positioned on the menu. Typical range is 0 (low priority. Eg: 'Get out') to 6 (high priority. Eg: 'Auto-hover on')

showWindow:

Boolean - (Optional, default true) if set to true, players see "Titletext" at mid-lower screen, as they approach the object. Only the title text for the action with highest priority and 'showWindow true' will be shown. Setting it to false disables the feature

hideOnUse:

Boolean - (Optional, default true) if set to true, it will hide the action menu after selecting that action. If set to false, it will leave the action menu open and visible after selecting that action, leaving the same action highlighted, for the purpose of allowing you to reselect that same action quickly, or to select another action

shortcut:

String - (Optional, default "") one of the key names defined in bin.pbo (e.g. "moveForward"). Adding available shortcut will bind corresponding keyboard key to this action. Shortcut availability can be tested with inputAction command

condition:

String - (Optional, default "true") script code that must return true for the action to be shown. Special variables passed to the script code are:

• _target: Object - the object to which action is attached or, if the object is a unit inside of vehicle, the vehicle
• _this: Object - caller person to whom the action is shown (or not shown if condition returns false)
• _originalTarget: Object - the original object to which the action is attached, regardless if the object/unit is in a vehicle or not

⚠

• condition is evaluated on each frame in non-scheduled environment.
• condition is not evaluated if a dialog is open.
• If action is added to an object (and not to player) condition will only get evaluated IF player is closer than ~50m to the object surface AND is looking at the object.
• If action is added to player, condition is evaluated all the time.

radius:

Number - (Optional, default 50) maximum 3D distance in meters between the activating unit's eyePos and the object's memoryPoint, selection or position. -1 disables the radius
Template:since

unconscious:

Boolean - (Optional, default false) if true will be shown to incapacitated player (see setUnconscious, lifeState)
Template:since

selection:

String - (Optional, default "") object Geometry LOD's named selection
Template:since

memoryPoint:

String - (Optional, default "") object's memory point. If selection is supplied, memoryPoint is not used
Template:since

Return Value:

Number - The added action's ID. Action can be removed with removeAction (see also removeAllActions). IDs are incrementing, the first given action to each unit has the ID 0, the second the ID 1, etc. IDs are also passed to the called script (see script parameter)

Examples

Example 1:

// short and sweet player addAction ["a useless action that does nothing", {}]; player addAction ["<t color='#FF0000'>This Useless Action Is RED</t>", {hint "RED"}]; player addAction ["Hint Hello!", { hint format ["Hello %1!", name player] }]; player addAction ["String Exec", "hint 'this is also compiled'"];

Example 2:

_actionID = player addAction ["Exec the file", "scriptFile.sqf"] scriptFile.sqf: hint str _this;

Example 3:

// create object on the server and add action to the object on every client if (isServer) then { private _object = "some_obj_class" createVehicle [1234, 1234, 0]; [_object, ["Greetings!", { hint "Hello!"; }]] remoteExec ["addAction"]; // Note: does not return action id };

Example 4:

Default parameters:this addAction [ "title", { params ["_target", "_caller", "_actionId", "_arguments"]; }, nil, 1.5, true, true, "", "true", // _target, _this, _originalTarget 50, false, "", "" ];

Example 5:

Default parameters with comments:this addAction [ "title", // title { params ["_target", "_caller", "_actionId", "_arguments"]; // script }, nil, // arguments 1.5, // priority true, // showWindow true, // hideOnUse "", // shortcut "true", // condition 50, // radius false, // unconscious "", // selection "" // memoryPoint ];

Additional Information

See also:

actionIDsactionParamssetUserActionTextinGameUISetEventHandlershowHUDinputAction removeActionremoveAllActionsactionBIS_fnc_holdActionAdd

Notes

Report bugs on the Feedback Tracker and/or discuss them on the Arma Discord or on the Forums.
Only post proven facts here! Add Note

Notes

Posted on May 02, 2018 - 13:44 (UTC)

Dedmen

If you want to replicate vanilla Actions like "Treat yourself" where the scroll menu only shows text and it displays the icon mid-screen you can use private _action = player addAction ["Heal", {}]; player setUserActionText [_action , "Heal", "<img size='2' image='\a3\ui_f\data\IGUI\Cfg\Actions\heal_ca'/>"];

Posted on May 12, 2020 - 10:42 (UTC)

PierreMGI

addAction on unit or player stays on corpse after kill. So this action is lost for the new body after respawn. If you want a persistent addAction, you need to add it in the respawn script (onPlayerRespawn.sqf or addMissionEventHandler "entityRespawned" or addMPEventHandler "MPrespawn"... You can use removeAllActions on corpse.