waitUntil

1.001.001.501.000.50

Hover & click on the images for description

Description

Description:

Suspends execution of scheduled script until the given condition satisfied.

• This command will loop and call the code inside {} mostly every frame, depends on complexity of the condition and the overall engine load, until the code returns true
• If the very first execution of the code returns true the command will exit immediately, therefore it will not produce any "Suspending not allowed in this context" error when used inside non-scheduled script. For all other uses it must be executed in environment that allows suspension (canSuspend), such as spawned or execVMed code
• Avoid doing waitUntil { time > 20 }; and use sleep 20; instead!
• If you can, add a sleep to the condition to save some cpu cycles waitUntil { sleep 1; !alive player };

Since Arma 3 v1.94, a condition returning anything other than true or false will result in an appropriate type error.

Problems:

For some unknown reason if you have waitUntil loop active and game is saved/loaded, some variables in the expression may appear undefined for a short time. As a workaround, assign expression to a variable and make sure it is defined before waitUntil checks it:

waitUntil { private _expression = var1 && (var2 > 10); !isNil "_expression" && { _expression } };

Groups:

Program Flow

Syntax

Syntax:

waitUntil condition

Parameters:

condition: Code - the expression that must return a Boolean, true to finish waiting or false to continue waiting

Return Value:

Anything - the value the condition evaluates to when the wait is over (normally true)

Examples

Example 1:

waitUntil { not alive player };

Example 2:

_i = 0; waitUntil { _i = _i + 1; _i >= 100 };

Example 3:

waitUntil can lead to performance loss if used improperly:

waitUntil { not alive player }; // bad waitUntil { sleep 1; not alive player }; // good - checks every 1 second player addEventHandler ["Killed", { }]; // best - don't forget about Event Handlers

Example 4:

An on-the-fly custom event handler:

_myEH = ["ZoomIn"] spawn { while { true } do { waitUntil { inputAction (_this select 0) == 1 }; diag_log format ["%1 @ %2", _this select 0, diag_tickTime]; }; };

Although it may be better to use onEachFrame (stacked) mission Event Handler, depending on the application.

Example 5:

Use getVariable with default value to prevent unexcepted script errors:

waitUntil { bank getVariable ["money", 0] > 0 }; waitUntil { missionNamespace getVariable ["isready", false] };

Example 6:

Always return Boolean:

waitUntil { sleep 1; if (not alive player) exitWith {}; _time = _time + 1 }; // bad waitUntil { sleep 1; if (not alive player) exitWith { true }; _time = _time + 1; false }; // good waitUntil { sleep 1; not alive player }; // perfect

Additional Information

See also:

sleep uiSleep canSuspend spawn execVM while Control Structures

Notes

Report bugs on the Feedback Tracker and/or discuss them on the Arma Discord or on the Forums.
Only post proven facts here! Add Note

CrashDome - c

Posted on Dec 20, 2006 - 19:55 (UTC)

waitUntil suspends both SQF functions and SQF scripts. In functions, the calling script is still in suspension due to waiting for a return from the call command. The game engine will continue, however. See Function for more detail.

Roehre - c

Posted on Apr 02, 2010 - 17:10 (UTC)

Prior to Arma 3 v1.94 if waitUntil uses an undefined call code, waitUntil won't release, even when this code is separated from other conditions through or. Be warned that this won't cause an error message.

Commy2 - c

Posted on Dec 13, 2014 - 23:25 (UTC)

If you want to use waitUntil together with exitWith, remember that the loop only exits if the code block returns true.

It should look like this:

waitUntil { // exit loop if the unit gets deleted if (isNull _unit) exitWith { true }; // has to return true to continue !alive _unit; };

AgentRev - c

Posted on Apr 19, 2022 - 06:05 (UTC)

It's a good idea to include a timeout with the condition if there's any possibility that it never becomes true:

disableUserInput true; player moveInDriver _vehicle; // this command is asynchronous and can fail sometimes _time = time; waitUntil {vehicle player == _vehicle || time - _time > 3}; disableUserInput false;