1.50

GAGlobal

Hover & click on the images for description

Description

Description:

Returns a list of intersections with surfaces and ground from begPosASL to endPosASL. Doesn't return intersection with sea surface. Works underwater, unlike lineIntersects. Hardcoded max distance: 5000m.

⚠

• if begPosASL is under the ground and endPosASL is above it, the command will only return intersection with the ground, this is an engine limitation and none of the intersectXXX commands will work when initiated from under the ground.
• only a single LOD is checked for intersection. LOD2 will only be checked if LOD1 is unavailable.

Since 2.20, there is an alternative syntax that does multiple checks in parallel, faster than multiple calls.

Groups:

Math - Geometry

Syntax

Syntax:

lineIntersectsSurfaces [begPosASL, endPosASL, ignoreObj1, ignoreObj2, sortMode, maxResults, LOD1, LOD2, returnUnique]

Parameters:

begPosASL: Array format PositionASL - virtual line start

endPosASL: Array format PositionASL - virtual line end

ignoreObj1: Object - (Optional, default objNull) first object to ignore

ignoreObj2: Object - (Optional, default objNull) second object to ignore

sortMode: Boolean - (Optional, default true) true: closest to furthest, false: furthest to closest

maxResults: Number - (Optional, default 1) max results to return. -1 to return every result

since 1.52

LOD1: String - (Optional, default "VIEW") primary LOD to look for intersection. Can be one of:

• "FIRE"
• "VIEW"
• "GEOM"
• "IFIRE" - ("I" stands for Indirect, almost identical to "FIRE")
• "NONE"
• 2.02 "PHYSX" - PhysX geometry LOD
• 2.08 "ROADWAY" - only works from the top

since 1.52

LOD2: String - (Optional, default "FIRE") secondary LOD to look for intersection. See LOD1 for possible values

since 1.70

returnUnique: Boolean - (Optional, default true) when false, all intersections in the same object are included, otherwise only the first one

Return Value:

Array of intersections in format [[intersectPosASL, surfaceNormal, intersectObj, parentObject, selectionNames, pathToBisurf], ...] where:

• intersectPosASL: PositionASL - the actual position where line intersects surface
• surfaceNormal: Vector - a normal to the intersected surface
• intersectObject: Object - the object the surface belongs to (could be proxy object) - objNull if terrain
• parentObject: Object - the object proxy object belongs to (not always the same as intersect object) - objNull if terrain
• 2.10 selectionNames: Array of Strings - Names of the intersected selections (bones). Returns [] if there is no intersection with a selection.
• 2.10 pathToBisurf: String - path to intersected surface properties (.bisurf) file. Returns "" if surface has no special properties. Terrain surface properties begin with #, and the surface properties are defined in CfgSurfaces. For example, if it returns #GdtVRsurface01, properties are defined in: cconfigFile >> "CfgSurfaces" >> "GdtVRsurface01"

2.20

Alternative Syntax

Syntax:

lineIntersectsSurfaces [element1, element2, ...]

Parameters:

elementN: Array format [begPosASL, endPosASL, ignoreObj1, ignoreObj2, sortMode, maxResults, LOD1, LOD2, returnUnique]

• begPosASL: Array format PositionASL - virtual line start
• endPosASL: Array format PositionASL - virtual line end
• ignoreObj1: Object - (Optional, default objNull) first object to ignore
• ignoreObj2: Object - (Optional, default objNull) second object to ignore
• sortMode: Boolean - (Optional, default true) true: closest to furthest, false: furthest to closest
• maxResults: Number - (Optional, default 1) max results to return. -1 to return every result
• LOD1: String - (Optional, default "VIEW") primary LOD to look for intersection. Can be one of:
  • "FIRE"
  • "VIEW"
  • "GEOM"
  • "IFIRE" - ("I" stands for Indirect, almost identical to "FIRE")
  • "NONE"
  • "PHYSX" - PhysX geometry LOD
  • "ROADWAY" - only works from the top
• LOD2: String - (Optional, default "FIRE") secondary LOD to look for intersection. See LOD1 for possible values
• returnUnique: Boolean - (Optional, default true) when false, all intersections in the same object are included, otherwise only the first one

Return Value:

Array format [result1, result2, ...] - each result is an Array of intersections in format [[intersectPosASL, surfaceNormal, intersectObj, parentObject, selectionNames, pathToBisurf], ...]

• intersectPosASL: PositionASL - the actual position where line intersects surface
• surfaceNormal: Vector - a normal to the intersected surface
• intersectObject: Object - the object the surface belongs to (could be proxy object) - objNull if terrain
• parentObject: Object - the object proxy object belongs to (not always the same as intersect object) - objNull if terrain
• selectionNames: Array of Strings - Names of the intersected selections (bones). Returns [] if there is no intersection with a selection.
• pathToBisurf: String - path to intersected surface properties (.bisurf) file. Returns "" if surface has no special properties. Terrain surface properties begin with #, and the surface properties are defined in CfgSurfaces. For example, if it returns #GdtVRsurface01, properties are defined in: cconfigFile >> "CfgSurfaces" >> "GdtVRsurface01"

Examples

Example 1:

Copy

_intersections = lineIntersectsSurfaces [eyePos player, aimPos chopper, player, chopper, true, -1];

Example 2:

Copy

arrow = "Sign_Arrow_F" createVehicle [0,0,0]; onEachFrame { _ins = lineIntersectsSurfaces [ AGLToASL positionCameraToWorld [0,0,0], AGLToASL positionCameraToWorld [0,0,1000], player ]; if (count _ins == 0) exitWith { arrow setPosASL [0,0,0] }; arrow setPosASL (_ins select 0 select 0); arrow setVectorUp (_ins select 0 select 1); hintSilent str _ins; };

Example 3:

This should detect glass windows and wire fences (since Arma 3 v1.52):

Copy

wirefence = "Land_New_WiredFence_5m_F" createVehicle position player; arrow = "Sign_Arrow_F" createVehicle [0,0,0]; onEachFrame { _ins = lineIntersectsSurfaces [ AGLToASL positionCameraToWorld [0,0,0], AGLToASL positionCameraToWorld [0,0,1000], player, objNull, true, 1, "GEOM", "NONE" ]; if (count _ins == 0) exitWith { arrow setPosASL [0,0,0] }; arrow setPosASL (_ins select 0 select 0); arrow setVectorUp (_ins select 0 select 1); hintSilent str _ins; };

Example 4:

Alternative syntax to check intersections in parallel. Will draw a redline to the first intersecting object between the player and unit:

Copy

private _handle = addMissionEventHandler ["Draw3D", { private _enemies = units opfor; private _enemyDataArray = _enemies apply { [eyePos player, eyePos _x, player, _x] }; private _intersections = lineIntersectsSurfaces [_enemyDataArray]; { // No intersections found, draw green '+' icon at unit if (_x isEqualTo []) then { drawIcon3D [ "\a3\ui_f\data\gui\cfg\cursors\add_gs.paa", [0, 1, 0, 1], ASLToAGL (eyePos (_enemies#_forEachIndex)), 0.5, 0.5, 0, str (_enemies#_forEachIndex) ]; } else { private _firstIntersection = _x#0; // Draw red line and '+' icon to first intersecting object drawIcon3D [ "\a3\ui_f\data\gui\cfg\cursors\add_gs.paa", [1, 0, 0, 1], ASLToAGL (_firstIntersection#0), 0.5, 0.5, 0, str (_enemies#_forEachIndex) + "- Blocked by " + str (_firstIntersection#2) ]; drawLine3D [ ASLToAGL (eyePos player), ASLToAGL (_firstIntersection#0), [1, 0, 0, 1], 5 ]; }; } forEach _intersections; }];

Additional Information

See also:

lineIntersectsObjs lineIntersectsWith lineIntersects terrainIntersectASL terrainIntersectAtASL terrainIntersect intersect cursorObject cursorTarget checkVisibility

Notes

Report bugs on the Feedback Tracker and/or discuss them on the Arma Discord or on the Forums.
Only post proven facts here! Add Note